[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Monday, October 22, 2018 @ 22:54:29
  Author: anthraxx
Revision: 398565

addpkg: python-sqlalchemy-continuum 1.3.6-1

Added:
  python-sqlalchemy-continuum/
  python-sqlalchemy-continuum/repos/
  python-sqlalchemy-continuum/trunk/
  python-sqlalchemy-continuum/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: python-sqlalchemy-continuum/trunk/PKGBUILD
===================================================================
--- python-sqlalchemy-continuum/trunk/PKGBUILD	                        (rev 0)
+++ python-sqlalchemy-continuum/trunk/PKGBUILD	2018-10-22 22:54:29 UTC (rev 398565)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org
+
+_pkgname=sqlalchemy-continuum
+pkgname=python-sqlalchemy-continuum
+pkgver=1.3.6
+pkgrel=1
+pkgdesc='Versioning and auditing extension for SQLAlchemy'
+url='https://github.com/kvesteri/sqlalchemy-continuum'
+arch=('any')
+license=('BSD')
+depends=('python' 'python-sqlalchemy' 'python-sqlalchemy-utils')
+makedepends=('python-setuptools' 'python-sphinx')
+checkdepends=('sqlite' 'python-pytest' 'python-flexmock' 'python-psycopg2' 'python-mysql-connector'
+              'python-six' 'python-anyjson' 'python-flask' 'python-flask-login' 'python-flask-sqlalchemy'
+              'python-sqlalchemy-i18n')
+optdepends=('python-flask: flask plugin'
+            'python-flask-login: flask plugin'
+            'python-flask-sqlalchemy: flask plugin'
+            'python-sqlalchemy-i18n: internationalization')
+options=('!makeflags')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/kvesteri/sqlalchemy-continuum/archive/${pkgver}.tar.gz)
+sha512sums=('dd0fea44f4f928b458291bfcdb632b1b447402648ed6c415a4bb1cca43bf19bd95b09b8f0447ee39432bf1e186d8bc919d1ca65b63d91631ebc56ed9a2e44f26')
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py build
+  make -C docs text man
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst docs/_build/text/* -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/sqlalchemy-continuum.1 -t "${pkgdir}/usr/share/man/man1"
+  ln -sf /usr/share/man/man1/sqlalchemy-continuum.1.gz "${pkgdir}/usr/share/man/man1/${pkgname}.1.gz"
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}/tests
+  DB=sqlite pytest
+}
+
+# vim: ts=2 sw=2 et: