[arch-commits] Commit in gnome-epub-thumbnailer/trunk (PKGBUILD)
Jan Steffens
heftig at archlinux.org
Sat Oct 27 15:56:28 UTC 2018
Date: Saturday, October 27, 2018 @ 15:56:27
Author: heftig
Revision: 337380
1.5-1: FS#58972 add thumbnailer
Added:
gnome-epub-thumbnailer/trunk/PKGBUILD
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-10-27 15:56:27 UTC (rev 337380)
@@ -0,0 +1,41 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-epub-thumbnailer
+pkgver=1.5
+pkgrel=1
+pkgdesc="Thumbnailer for EPub and MOBI books"
+url="https://gitlab.gnome.org/GNOME/gnome-epub-thumbnailer"
+license=(GPL)
+arch=(x86_64)
+_commit=cce8d8e594ef8fe77720ca33656c2f4368cd424a # tags/1.5^0
+depends=(gdk-pixbuf2 libarchive libxml2)
+makedepends=(git gnome-common)
+source=("git+https://gitlab.gnome.org/GNOME/gnome-epub-thumbnailer.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+ --enable-compile-warnings=minimum
+ make
+}
+
+check() {
+ make -C $pkgname check
+}
+
+package() {
+ DESTDIR="$pkgdir" make -C $pkgname install
+}
+
+# vim:set sw=2 et:
Property changes on: gnome-epub-thumbnailer/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list