[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Wednesday, October 31, 2018 @ 18:38:15
  Author: archange
Revision: 400460

Initial addition of nodejs-lts-dubnium

Added:
  nodejs-lts-dubnium/
  nodejs-lts-dubnium/repos/
  nodejs-lts-dubnium/trunk/
  nodejs-lts-dubnium/trunk/PKGBUILD

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Added: nodejs-lts-dubnium/trunk/PKGBUILD
===================================================================
--- nodejs-lts-dubnium/trunk/PKGBUILD	                        (rev 0)
+++ nodejs-lts-dubnium/trunk/PKGBUILD	2018-10-31 18:38:15 UTC (rev 400460)
@@ -0,0 +1,67 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=nodejs-lts-dubnium
+pkgver=10.13.0
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript (LTS release: Dubnium)'
+arch=('x86_64')
+url="https://nodejs.org/"
+license=('MIT')
+depends=('openssl' 'zlib' 'icu' 'libuv' 'http-parser' 'c-ares' 'libnghttp2')
+makedepends=('python2' 'procps-ng')
+optdepends=('npm: nodejs package manager')
+provides=("nodejs=$pkgver")
+conflicts=('nodejs')
+source=("${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz")
+# https://nodejs.org/download/release/latest-dubnium/SHASUMS256.txt.asc
+sha256sums=('8d80c96a0c28fb508c90de474b1967acd800896f184b8a18235a7e4613fae641')
+validpgpkeys=('C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8' # Myles Borins <mylesborins at google.com>
+              '77984A986EBC2AA786BC0F66B01FBB92821C587A' # Gibson Fahnestock <gibfahn at gmail.com>
+              'B9AE9905FFD7803F25714661B63B535A4C206CA9' # Evan Lucas <evanlucas at me.com> 
+              'DD8F2338BAE7501E3DD5AC78C273792F7D83545D') # Rod Vagg <rod at vagg.org>
+
+prepare() {
+  cd node-v${pkgver}
+
+  msg 'Fixing for python2 name'
+  find -type f -exec sed \
+    -e 's_^#!/usr/bin/env python$_&2_' \
+    -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
+    -e 's_^#!/usr/bin/python$_&2_' \
+    -e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
+    -e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
+    -e "s_'python'_'python2'_" -i {} \;
+  find test/ -type f -exec sed 's_python _python2 _' -i {} \;
+}
+
+build() {
+  cd node-v${pkgver}
+
+  export PYTHON=python2
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --shared-http-parser \
+    --shared-cares \
+    --shared-nghttp2
+
+  make
+}
+
+check() {
+  cd node-v${pkgver}
+  # Expected failure: https://github.com/nodejs/node/issues/11627
+  make test || warning "Tests failed"
+}
+
+package() {
+  cd node-v${pkgver}
+
+  make DESTDIR="${pkgdir}" install
+
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}