[arch-commits] Commit in haskell-hpack/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Sep 3 11:40:42 UTC 2018


    Date: Monday, September 3, 2018 @ 11:40:42
  Author: felixonmars
Revision: 376381

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hpack/repos/community-staging-x86_64/
  haskell-hpack/repos/community-staging-x86_64/PKGBUILD
    (from rev 376380, haskell-hpack/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-hpack/repos/community-staging-x86_64/PKGBUILD (from rev 376380, haskell-hpack/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-03 11:40:42 UTC (rev 376381)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+pkgname=haskell-hpack
+_hkgname=hpack
+pkgver=0.30.0
+pkgrel=1
+pkgdesc="A modern format for Haskell packages"
+url="https://github.com/sol/hpack#readme"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-bifunctors' 'haskell-cryptonite' 'haskell-glob'
+         'haskell-http-client' 'haskell-http-client-tls' 'haskell-http-types'
+         'haskell-infer-license' 'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-hspec' 'haskell-interpolate'
+             'haskell-mockery' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
+sha512sums=('76cf9c682293e4d9b906fc875ef400ccebc483f7c5db2a5a16b9a85cae1cf6a52daed1a89859a3e377172ef2385ff307d2a963a2b12dbc66381ddbd6b7bdb258')
+
+build() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
+}



More information about the arch-commits mailing list