[arch-commits] Commit in python-aiohttp/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Levente Polyak]

    Date: Monday, September 3, 2018 @ 21:28:31
  Author: anthraxx
Revision: 376463

archrelease: copy trunk to community-x86_64

Added:
  python-aiohttp/repos/community-x86_64/PKGBUILD
    (from rev 376462, python-aiohttp/trunk/PKGBUILD)
Deleted:
  python-aiohttp/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   84 ++++++++++++++++++++++++++++++++++++-------------------------
 1 file changed, 50 insertions(+), 34 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-09-03 21:28:00 UTC (rev 376462)
+++ PKGBUILD	2018-09-03 21:28:31 UTC (rev 376463)
@@ -1,34 +0,0 @@
-# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
-# Contributor: Philipp A. <flying-sheep at web.de>
-
-_pkgname=aiohttp
-pkgname=python-aiohttp
-pkgver=3.2.1
-pkgrel=2
-pkgdesc='HTTP client/server for asyncio'
-url='https://aiohttp.readthedocs.io'
-arch=('x86_64')
-license=('Apache')
-depends=('python' 'python-chardet' 'python-multidict' 'python-async-timeout' 'python-yarl' 'python-idna_ssl' 'python-attrs')
-makedepends=('cython' 'python-setuptools')
-checkdepends=('python-pytest' 'python-pytest-runner' 'python-pytest-mock' 'python-async_generator')
-source=(${pkgname}-${pkgver}.tar.gz::https://github.com/aio-libs/aiohttp/archive/v${pkgver}.tar.gz)
-sha256sums=('6cf1c7fd052bc92e0be940e5b2e877a202d2d0fdf36cbf2aa3ef3c92f4e2327a')
-sha512sums=('c56bbcd09bcb56cea1ee2977a7550a0dcde1a18e58e50340978e8882a483350f092b06314611e62e90964a357252debddaf031af427910f318efa31720f3dc33')
-
-build() {
-  cd ${_pkgname}-${pkgver}
-  python setup.py build
-}
-
-check() {
-  cd ${_pkgname}-${pkgver}
-  python setup.py test
-}
-
-package() {
-  cd ${_pkgname}-${pkgver}
-  python setup.py install --root="${pkgdir}" -O1 --skip-build
-}
-
-# vim: ts=2 sw=2 et:

Copied: python-aiohttp/repos/community-x86_64/PKGBUILD (from rev 376462, python-aiohttp/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-09-03 21:28:31 UTC (rev 376463)
@@ -0,0 +1,50 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Philipp A. <flying-sheep at web.de>
+
+_pkgname=aiohttp
+pkgname=python-aiohttp
+_gitcommit=3ddd91c2c89e5a31380b169bd5a26c8d641b2fc5
+pkgver=3.4.2
+pkgrel=1
+pkgdesc='HTTP client/server for asyncio'
+url='https://aiohttp.readthedocs.io'
+arch=('x86_64')
+license=('Apache')
+depends=('python' 'python-chardet' 'python-multidict' 'python-async-timeout'
+         'python-yarl' 'python-attrs')
+makedepends=('cython' 'python-setuptools' 'git')
+checkdepends=('python-pytest' 'python-pytest-runner' 'python-pytest-mock'
+              'python-pytest-timeout' 'python-async_generator' 'python-brotlipy')
+source=(${pkgname}::"git+https://github.com/aio-libs/aiohttp#commit=${_gitcommit}"
+        git+https://github.com/nodejs/http-parser)
+sha512sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  git describe --always --tags | sed 's/^v//;s/-/./g'
+}
+
+prepare() {
+  cd ${pkgname}
+  git submodule init
+  git config submodule."vendor/http-parser".url "${srcdir}/http-parser"
+  git submodule update --recursive
+}
+
+build() {
+  cd ${pkgname}
+  python setup.py build
+}
+
+check() {
+  cd ${pkgname}
+  python setup.py test
+}
+
+package() {
+  cd ${pkgname}
+  python setup.py install --root="${pkgdir}" -O1 --skip-build
+}
+
+# vim: ts=2 sw=2 et: