[arch-commits] Commit in gobject-introspection/repos (2 files)
Jan Steffens
heftig at archlinux.org
Tue Sep 4 16:55:39 UTC 2018
Date: Tuesday, September 4, 2018 @ 16:55:38
Author: heftig
Revision: 333305
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gobject-introspection/repos/gnome-unstable-x86_64/
gobject-introspection/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 333304, gobject-introspection/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: gobject-introspection/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333304, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-09-04 16:55:38 UTC (rev 333305)
@@ -0,0 +1,54 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.58.0
+pkgrel=1
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+depends=(python python-mako)
+makedepends=(cairo git gtk-doc python-sphinx meson)
+options=(!emptydirs)
+_commit=01bf21f398d5ece9ac2d78c00b4b362091f8e05c # tags/1.58.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+}
+
+build() {
+ arch-meson $pkgbase build -D cairo=true -D gtk-doc=true
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package_gobject-introspection() {
+ depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+ DESTDIR="$pkgdir" meson install -C build
+ python -m compileall "$pkgdir/usr/lib/gobject-introspection"
+ python -O -m compileall "$pkgdir/usr/lib/gobject-introspection"
+
+### Split runtime
+ mkdir -p "$srcdir/runtime/lib"
+ mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
+}
+
+package_gobject-introspection-runtime() {
+ pkgdesc+=" (runtime library)"
+ depends=(glib2)
+
+ mv "$srcdir/runtime" "$pkgdir/usr"
+}
More information about the arch-commits
mailing list