[arch-commits] Commit in webkit2gtk/repos (2 files)
Jan Steffens
heftig at archlinux.org
Tue Sep 4 19:41:41 UTC 2018
Date: Tuesday, September 4, 2018 @ 19:41:41
Author: heftig
Revision: 333334
archrelease: copy trunk to gnome-unstable-x86_64
Added:
webkit2gtk/repos/gnome-unstable-x86_64/
webkit2gtk/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 333333, webkit2gtk/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: webkit2gtk/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333333, webkit2gtk/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-09-04 19:41:41 UTC (rev 333334)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=webkit2gtk
+pkgver=2.22.0
+pkgrel=1
+pkgdesc="GTK+ Web content engine library"
+arch=(x86_64)
+url="https://webkitgtk.org/"
+license=(custom)
+depends=(libxt libxslt enchant geoclue2 gst-plugins-base-libs
+ libsecret libwebp harfbuzz-icu gtk3 libnotify hyphen woff2)
+makedepends=(gtk2 gperf gobject-introspection ruby gtk-doc cmake python python2 ninja)
+optdepends=('gtk2: Netscape plugin support'
+ 'gst-plugins-base: free media decoding'
+ 'gst-plugins-good: media decoding'
+ 'gst-libav: nonfree media decoding')
+source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
+sha256sums=('fa42b54a98831405c8a3e7f40371eec3f0bd5cdbb124813a5e329e7a9f8c6f2a'
+ 'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3')
+
+prepare() {
+ mkdir build
+ cd webkitgtk-$pkgver
+ sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
+}
+
+build() {
+ cd build
+ cmake ../webkitgtk-$pkgver -G Ninja \
+ -DPORT=GTK \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DENABLE_GTKDOC=ON \
+ -DLIBEXEC_INSTALL_DIR=/usr/lib \
+ -DLIB_INSTALL_DIR=/usr/lib \
+ -DPYTHON_EXECUTABLE=/usr/bin/python2
+ cmake --build .
+}
+
+check() {
+ : cmake --build build --target tests
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --build build --target install
+
+ cd webkitgtk-$pkgver
+ find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+ while IFS= read -d $'\0' -r _f; do
+ echo "### $_f ###"
+ cat "$_f"
+ echo
+ done |
+ install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list