[arch-commits] Commit in gjs/repos (2 files)

[Jan Steffens]

    Date: Tuesday, September 4, 2018 @ 23:57:50
  Author: heftig
Revision: 333357

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gjs/repos/gnome-unstable-x86_64/
  gjs/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333356, gjs/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: gjs/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333356, gjs/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-04 23:57:50 UTC (rev 333357)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gjs
+pkgver=1.54.0
+pkgrel=1
+epoch=1
+pkgdesc="Javascript Bindings for GNOME"
+url="https://wiki.gnome.org/Projects/Gjs"
+arch=(x86_64)
+license=(GPL)
+depends=(cairo gobject-introspection-runtime js60 gtk3)
+makedepends=(gobject-introspection git autoconf-archive xorg-server-xvfb)
+checkdepends=(valgrind)
+_commit=d8dca63d7d508b858f771d847bee2e99017db2ce  # tags/1.54.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # We don't have C.UTF-8
+  sed -i 's|C\.UTF-8|en_US.UTF-8|g' Makefile-test.am test/test-ci.sh
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --libexecdir=/usr/lib \
+    --disable-static \
+    --enable-compile-warnings=yes \
+    --with-xvfb-tests
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make -j1 check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}