[arch-commits] Commit in evince/repos (2 files)

[Jan Steffens]

    Date: Wednesday, September 5, 2018 @ 18:24:59
  Author: heftig
Revision: 333524

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evince/repos/gnome-unstable-x86_64/
  evince/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333523, evince/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: evince/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333523, evince/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-05 18:24:59 UTC (rev 333524)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evince
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="Document viewer (PDF, Postscript, djvu, tiff, dvi, XPS, SyncTex support with gedit, comics books (cbr,cbz,cb7 and cbt))"
+url="https://wiki.gnome.org/Apps/Evince"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre t1lib dconf libsecret
+         gsettings-desktop-schemas gnome-desktop libarchive gst-plugins-base-libs gspell)
+makedepends=(itstool libnautilus-extension texlive-bin gobject-introspection intltool docbook-xsl
+             python gtk-doc git gnome-common)
+optdepends=('texlive-bin: DVI support'
+            'gvfs: bookmark support and session saving')
+groups=(gnome)
+options=('!emptydirs')
+_commit=bfe177e42b460350893ce89c0f7a3ceaaf2953dc  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/evince.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+  
+build() {
+  cd $pkgname
+
+  BROWSER_PLUGIN_DIR=/usr/lib/epiphany/plugins \
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-static \
+    --enable-compile-warnings=minimum \
+    --enable-introspection \
+    --enable-nautilus \
+    --enable-pdf \
+    --enable-ps \
+    --enable-tiff \
+    --enable-djvu \
+    --enable-dvi \
+    --enable-t1lib \
+    --enable-comics \
+    --enable-gtk-doc \
+    --enable-multimedia \
+    --disable-schemas-compile
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}