[arch-commits] Commit in dbus-broker/repos (extra-x86_64 extra-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Wed Sep 5 18:38:49 UTC 2018
Date: Wednesday, September 5, 2018 @ 18:38:49
Author: heftig
Revision: 333530
archrelease: copy trunk to extra-x86_64
Added:
dbus-broker/repos/extra-x86_64/
dbus-broker/repos/extra-x86_64/PKGBUILD
(from rev 333529, dbus-broker/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: dbus-broker/repos/extra-x86_64/PKGBUILD (from rev 333529, dbus-broker/trunk/PKGBUILD)
===================================================================
--- extra-x86_64/PKGBUILD (rev 0)
+++ extra-x86_64/PKGBUILD 2018-09-05 18:38:49 UTC (rev 333530)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: David Herrmann <dh.herrmann at gmail.com>
+
+pkgname=dbus-broker
+pkgver=15
+pkgrel=2
+pkgdesc="Linux D-Bus Message Broker"
+url="https://github.com/bus1/dbus-broker"
+arch=(x86_64)
+license=(Apache)
+depends=(libsystemd expat glib2 audit)
+makedepends=(git meson systemd python-docutils)
+_commit=56fe1c3cfcd0737b017556b373a02320ccec68ff # tags/v15^0
+source=("git+https://github.com/bus1/dbus-broker#commit=$_commit"
+ git+https://github.com/c-util/c-{rbtree,sundry,list,dvar,utf8})
+sha256sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ local sm
+ git submodule init
+ for sm in c-{rbtree,sundry,list,dvar,utf8}; do
+ git config --local submodule.subprojects/$sm.url "$srcdir/$sm"
+ done
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build -D docs=true -D audit=true
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list