[arch-commits] Commit in swell-foop/repos (2 files)

Jan Steffens heftig at archlinux.org
Wed Sep 5 20:25:36 UTC 2018


    Date: Wednesday, September 5, 2018 @ 20:25:35
  Author: heftig
Revision: 333554

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  swell-foop/repos/gnome-unstable-x86_64/
  swell-foop/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333553, swell-foop/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: swell-foop/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333553, swell-foop/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-05 20:25:35 UTC (rev 333554)
@@ -0,0 +1,38 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=swell-foop
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="Clear the screen by removing groups of colored and shaped tiles"
+url="https://wiki.gnome.org/Apps/Swell%20Foop"
+arch=(x86_64)
+license=(GPL)
+depends=(clutter-gtk librsvg)
+makedepends=(gobject-introspection yelp-tools appstream-glib vala git meson)
+groups=(gnome-extra)
+_commit=307b6e3dca3394d0f30078ab864936625ba09eee  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/swell-foop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}



More information about the arch-commits mailing list