[arch-commits] Commit in gnome-tweaks/repos (2 files)

[Jan Steffens]

    Date: Wednesday, September 5, 2018 @ 20:39:17
  Author: heftig
Revision: 333558

archrelease: copy trunk to gnome-unstable-any

Added:
  gnome-tweaks/repos/gnome-unstable-any/
  gnome-tweaks/repos/gnome-unstable-any/PKGBUILD
    (from rev 333557, gnome-tweaks/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: gnome-tweaks/repos/gnome-unstable-any/PKGBUILD (from rev 333557, gnome-tweaks/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD	                        (rev 0)
+++ gnome-unstable-any/PKGBUILD	2018-09-05 20:39:17 UTC (rev 333558)
@@ -0,0 +1,37 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gnome-tweaks
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="Graphical interface for advanced GNOME 3 settings (Tweak Tool)"
+url="https://wiki.gnome.org/Apps/Tweaks"
+arch=(any)
+license=(GPL)
+depends=(gnome-settings-daemon python-gobject nautilus)
+makedepends=(git meson)
+groups=(gnome-extra)
+provides=("gnome-tweak-tool=$pkgver")
+conflicts=(gnome-tweak-tool)
+replaces=(gnome-tweak-tool)
+_commit=f2198f3a690f52f4714f04b06824090a28d79b32  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-tweaks.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}