[arch-commits] Commit in (4 files)
Jan Steffens
heftig at archlinux.org
Sat Sep 8 01:20:02 UTC 2018
Date: Saturday, September 8, 2018 @ 01:20:01
Author: heftig
Revision: 333878
community2extra: Moving gtksourceview4 from community to extra
Added:
gtksourceview4/
gtksourceview4/repos/
gtksourceview4/trunk/
gtksourceview4/trunk/PKGBUILD
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Added: gtksourceview4/trunk/PKGBUILD
===================================================================
--- gtksourceview4/trunk/PKGBUILD (rev 0)
+++ gtksourceview4/trunk/PKGBUILD 2018-09-08 01:20:01 UTC (rev 333878)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gtksourceview4
+pkgver=4.0.2
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME"
+url="https://wiki.gnome.org/Projects/GtkSourceView"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libxml2)
+makedepends=(intltool gobject-introspection glade vala gtk-doc autoconf-archive git)
+_commit=fb6c1941ec2e62ec8cfd3939a038f013663dfe3c # tags/4.0.2^0
+source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd gtksourceview
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd gtksourceview
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd gtksourceview
+ ./configure --prefix=/usr --sysconfdir=/etc \
+ --localstatedir=/var --disable-static \
+ --enable-gtk-doc --disable-Werror
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package() {
+ cd gtksourceview
+ make DESTDIR="$pkgdir" install
+}
Property changes on: gtksourceview4/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list