[arch-commits] Commit in gnome-music/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 8, 2018 @ 01:48:03
  Author: heftig
Revision: 333888

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-music/repos/gnome-unstable-x86_64/
  gnome-music/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333887, gnome-music/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: gnome-music/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333887, gnome-music/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-08 01:48:03 UTC (rev 333888)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-music
+pkgver=3.30.0
+pkgrel=1
+epoch=1
+pkgdesc="Music player and management application"
+url="https://wiki.gnome.org/Apps/Music"
+arch=(x86_64)
+license=(GPL)
+depends=(grilo grilo-plugins tracker-miners libdmapsharing libmediaart gtk3 gvfs python-gobject
+         python-cairo gst-plugins-base python-requests libdazzle)
+makedepends=(gobject-introspection git meson yelp-tools appstream-glib)
+optdepends=('gst-plugins-good: Extra media codecs'
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs')
+groups=(gnome)
+_commit=f5eb3ca5d3fcfd117cc6fd67471adc53a944dc1b  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-music.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  python -m compileall "$pkgdir/usr/lib"
+  python -O -m compileall "$pkgdir/usr/lib"
+}