[arch-commits] Commit in gnome-builder/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 8, 2018 @ 01:55:29
  Author: heftig
Revision: 333898

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-builder/repos/gnome-unstable-x86_64/
  gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333897, gnome-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333897, gnome-builder/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-08 01:55:29 UTC (rev 333898)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-builder
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="An IDE for writing GNOME-based software"
+url="https://wiki.gnome.org/Apps/Builder"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtksourceview4 devhelp libgit2-glib gjs python-gobject clang desktop-file-utils
+         ctags libpeas vte3 vala python-jedi autoconf-archive sysprof flatpak gspell libdazzle
+         template-glib jsonrpc-glib python-sphinx webkit2gtk)
+makedepends=(intltool llvm gobject-introspection gtk-doc yelp-tools appstream-glib vala git
+             mm-common meson)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-code-assistance: Legacy assistance services')
+groups=(gnome-extra)
+_commit=81a9a8235f3c9818147cd1a710ac870bed4c5938  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-builder.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git cherry-pick -n ba4d103
+}
+
+build() {
+  arch-meson $pkgname build \
+    --buildtype debugoptimized \
+    -D with_docs=true \
+    -D with_help=true \
+    -D with_editorconfig=true \
+    -D with_webkit=true \
+    -D with_vapi=true
+  ninja -C build
+}
+
+check() {
+  # some tests need an installed gnome-builder
+  xvfb-run meson test -C build || :
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: