[arch-commits] Commit in gedit/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 8, 2018 @ 01:58:21
  Author: heftig
Revision: 333900

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gedit/repos/gnome-unstable-x86_64/
  gedit/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333899, gedit/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gedit/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333899, gedit/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-08 01:58:21 UTC (rev 333900)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gedit
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="GNOME Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit"
+arch=(x86_64)
+license=(GPL)
+depends=(gtksourceview3 gsettings-desktop-schemas libpeas gspell python-gobject dconf)
+makedepends=(yelp-tools intltool vala gobject-introspection gnome-common git gtk-doc)
+optdepends=('gedit-plugins: Additional features')
+groups=(gnome)
+_commit=ad626786357e83821b1b1eed6c8b4612a3ede2c5  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.libgd.url "$srcdir/libgd"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+      --sysconfdir=/etc --localstatedir=/var \
+      --libexecdir=/usr/lib --disable-updater --disable-schemas-compile \
+      --enable-python --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package(){
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}