[arch-commits] Commit in gedit-plugins/repos (2 files)
Jan Steffens
heftig at archlinux.org
Sat Sep 8 02:03:18 UTC 2018
Date: Saturday, September 8, 2018 @ 02:03:18
Author: heftig
Revision: 333906
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gedit-plugins/repos/gnome-unstable-x86_64/
gedit-plugins/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 333905, gedit-plugins/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: gedit-plugins/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333905, gedit-plugins/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-09-08 02:03:18 UTC (rev 333906)
@@ -0,0 +1,46 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Hugo Doria <hugo at archlinux.org>
+# Contributor: Sergej Chodarev <sergejx at centrum.sk>
+# Contributor: zhuqin <zhuqin83 at gmail.com>
+
+pkgname=gedit-plugins
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="Collection of plugins for the gedit Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit/ShippedPlugins"
+arch=(x86_64)
+license=(GPL)
+depends=(gedit python-dbus python-cairo)
+makedepends=(intltool vte3 libgit2-glib itstool gucharmap gobject-introspection vala yelp-tools git)
+optdepends=('gucharmap: for charmap plugin'
+ 'vte3: for embedded terminal'
+ 'libgit2-glib: for git plugin')
+_commit=4fdb7da1b03ab5f0eda3e74382fc87c3c67a40b0 # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit-plugins.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list