[arch-commits] Commit in gnome-documents/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 8, 2018 @ 02:11:06
  Author: heftig
Revision: 333913

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-documents/repos/gnome-unstable-x86_64/
  gnome-documents/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 333912, gnome-documents/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: gnome-documents/repos/gnome-unstable-x86_64/PKGBUILD (from rev 333912, gnome-documents/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-09-08 02:11:06 UTC (rev 333913)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-documents
+pkgver=3.29.91+6+gbc9b6cc1
+pkgrel=1
+pkgdesc="A document manager application for GNOME"
+url="https://wiki.gnome.org/Apps/Documents"
+arch=(x86_64)
+license=(GPL)
+depends=(evince gjs gtk3 gnome-desktop gnome-online-accounts libgdata tracker-miners libzapojit
+         webkit2gtk gnome-online-miners librsvg libgepub)
+makedepends=(gobject-introspection git meson yelp-tools inkscape)
+optdepends=('libreoffice-fresh: Support for Libreoffice document types')
+groups=(gnome)
+_commit=bc9b6cc1838d0c97f6ae33c0f56ec1c7d3a32b48  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-documents.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git submodule update
+}
+  
+
+build() {
+  arch-meson $pkgname build -D getting_started=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set ts=2 sw=2 et: