[arch-commits] Commit in gnome-software/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 8, 2018 @ 03:09:40
  Author: heftig
Revision: 378747

archrelease: copy trunk to community-testing-x86_64

Added:
  gnome-software/repos/community-testing-x86_64/
  gnome-software/repos/community-testing-x86_64/PKGBUILD
    (from rev 378746, gnome-software/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: gnome-software/repos/community-testing-x86_64/PKGBUILD (from rev 378746, gnome-software/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-09-08 03:09:40 UTC (rev 378747)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=3.30.0
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL2)
+makedepends=(appstream-glib gnome-desktop libpackagekit-glib flatpak fwupd ostree
+             docbook-xsl git gobject-introspection gspell gtk-doc meson valgrind)
+_commit=9f58ded14e355f663f4287dc3ce8802f4ece3547  # tags/3.30.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D ubuntuone=false \
+    -D ubuntu_reviews=false
+  ninja -C build
+}
+
+check() {
+  # build container troubles
+  meson test -C build || :
+}
+
+package_gnome-software() {
+  groups=('gnome')
+  depends=(appstream-glib gnome-desktop gsettings-desktop-schemas gspell libpackagekit-glib)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'ostree: OSTree support plugin')
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  # Split out packagekit plugin
+  mkdir "$srcdir"/packagekit-plugin
+  mv "$pkgdir"/usr/lib/gs-plugins-12/libgs_plugin_{packagekit*,systemd-updates}.so "$srcdir"/packagekit-plugin
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit)
+
+  mkdir -p "$pkgdir"/usr/lib/gs-plugins-12
+  mv "$srcdir"/packagekit-plugin/* "$pkgdir"/usr/lib/gs-plugins-12/
+}