[arch-commits] Commit in gmime3/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Monday, September 10, 2018 @ 22:49:48
  Author: foutrelis
Revision: 334347

archrelease: copy trunk to staging-x86_64

Added:
  gmime3/repos/staging-x86_64/
  gmime3/repos/staging-x86_64/PKGBUILD
    (from rev 334346, gmime3/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gmime3/repos/staging-x86_64/PKGBUILD (from rev 334346, gmime3/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-09-10 22:49:48 UTC (rev 334347)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Ben <ben at benmazer.net>
+
+pkgname=gmime3
+pkgver=3.2.0
+pkgrel=2
+pkgdesc="A C/C++ MIME creation and parser library with support for S/MIME, PGP, and Unix mbox spools"
+arch=(x86_64)
+license=(GPL)
+url="https://github.com/jstedfast/gmime"
+depends=(glib2 gpgme zlib)
+makedepends=(gobject-introspection gtk-doc git vala docbook-utils)
+_commit=7bae7f1dddf5e017548841a9803f8b0f505caa9f  # tags/3.2.0^0
+source=("git+https://github.com/jstedfast/gmime#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gmime
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gmime
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd gmime
+
+  ./configure --prefix=/usr \
+    --program-prefix=$pkgname \
+    --enable-gtk-doc \
+    --enable-smime \
+    --disable-static
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd gmime
+  make DESTDIR="$pkgdir" install
+}