[arch-commits] Commit in openal/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Tuesday, September 11, 2018 @ 12:57:01
  Author: heftig
Revision: 334374

archrelease: copy trunk to extra-x86_64

Added:
  openal/repos/extra-x86_64/PKGBUILD
    (from rev 334373, openal/trunk/PKGBUILD)
Deleted:
  openal/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  118 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 58 insertions(+), 60 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-09-11 12:56:43 UTC (rev 334373)
+++ PKGBUILD	2018-09-11 12:57:01 UTC (rev 334374)
@@ -1,60 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Allan McRae <allan at archlinux.org>
-# Contributor: Jason Chu <jchu at xentac.net>
-
-pkgbase=openal
-pkgname=(openal openal-examples)
-pkgver=1.18.2
-pkgrel=2
-pkgdesc="Cross-platform 3D audio library, software implementation"
-arch=(x86_64)
-url="https://github.com/kcat/openal-soft"
-license=(LGPL)
-depends=(glibc)
-makedepends=(alsa-lib libpulse fluidsynth portaudio jack qt5-base sdl2 sdl_sound ffmpeg
-             git cmake ninja)
-_commit=ce6076091bac3c00cd10803916e8911495580bd0  # tags/openal-soft-1.18.2
-source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
-sha512sums=('SKIP')
-
-pkgver() {
-  cd openal-soft
-  git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
-}
-
-prepare() {
-  mkdir build examples
-  cd openal-soft
-
-  # https://bugs.archlinux.org/task/54908
-  git cherry-pick -n d4f3490a880f779f460332689a396ade69840f50
-}
-
-build() {
-  cd build
-  cmake ../openal-soft -G Ninja \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_BUILD_TYPE=Release \
-    -DCMAKE_INSTALL_LIBDIR=lib
-  ninja
-}
-
-package_openal() {
-  optdepends=('qt5-base: alsoft-config GUI Configurator'
-              'fluidsynth: MIDI rendering')
-
-  DESTDIR="$pkgdir" ninja -C build install
-  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
-
-### Split openal-examples
-  mv -v "$pkgdir"/usr/bin/al{ffplay,hrtf,latency,loopback,reverb,stream} examples/
-}
-
-package_openal-examples() {
-  pkgdesc+=" (example programs)"
-  depends=("openal=$pkgver-$pkgrel" sdl2 sdl_sound ffmpeg)
-
-  mkdir "$pkgdir/usr"
-  mv -v examples "$pkgdir/usr/bin"
-}

Copied: openal/repos/extra-x86_64/PKGBUILD (from rev 334373, openal/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-09-11 12:57:01 UTC (rev 334374)
@@ -0,0 +1,58 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jason Chu <jchu at xentac.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.19.0
+pkgrel=1
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL)
+depends=(glibc)
+makedepends=(alsa-lib libpulse fluidsynth portaudio jack qt5-base sdl2 sdl_sound ffmpeg
+             git cmake ninja)
+_commit=96aacac10ca852fc30fd7f72f3e3c6ddbe02858c  # tags/openal-soft-1.19.0
+source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd openal-soft
+  git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
+}
+
+prepare() {
+  mkdir build examples
+  cd openal-soft
+}
+
+build() {
+  cd build
+  cmake ../openal-soft -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  ninja
+}
+
+package_openal() {
+  optdepends=('qt5-base: alsoft-config GUI Configurator'
+              'fluidsynth: MIDI rendering')
+
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
+
+### Split openal-examples
+  cd "$pkgdir/usr/bin"
+  mv -vt "$srcdir/examples" alffplay alhrtf allatency alloopback almultireverb \
+    alplay alrecord alreverb alstream altonegen
+}
+
+package_openal-examples() {
+  pkgdesc+=" (example programs)"
+  depends=("openal=$pkgver-$pkgrel" sdl2 sdl_sound ffmpeg)
+
+  mkdir "$pkgdir/usr"
+  mv -v examples "$pkgdir/usr/bin"
+}