[arch-commits] Commit in libtool/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at archlinux.org
Tue Sep 11 19:51:40 UTC 2018
Date: Tuesday, September 11, 2018 @ 19:51:39
Author: foutrelis
Revision: 334394
archrelease: copy trunk to testing-x86_64
Added:
libtool/repos/testing-x86_64/
libtool/repos/testing-x86_64/PKGBUILD
(from rev 334393, libtool/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: libtool/repos/testing-x86_64/PKGBUILD (from rev 334393, libtool/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-09-11 19:51:39 UTC (rev 334394)
@@ -0,0 +1,50 @@
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+# NOTE: requires rebuilt with each new gcc version
+
+pkgname=libtool
+pkgver=2.4.6+42+gb88cebd5
+pkgrel=2
+_gccver=8.2.1
+pkgdesc='A generic library support script'
+arch=(x86_64)
+url='http://www.gnu.org/software/libtool'
+license=(GPL)
+groups=(base-devel)
+depends=(sh tar glibc)
+makedepends=("gcc>=$_gccver" git help2man)
+checkdepends=(gcc-fortran)
+provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
+conflicts=(libltdl libtool-multilib)
+replaces=(libltdl libtool-multilib)
+_commit=b88cebd510add4420dd8f5367e3cc6e6e1f267cd
+source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit)
+md5sums=('SKIP')
+
+pkgver() {
+ cd libtool
+ git describe --tags | sed 's/-/+/g;s/^v//'
+}
+
+prepare() {
+ cd libtool
+ ./bootstrap
+}
+
+build() {
+ cd libtool
+ ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
+ make
+}
+
+check() {
+ cd libtool
+ make check gl_public_submodule_commit=
+}
+
+package() {
+ cd libtool
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list