[arch-commits] Commit in vino/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Wednesday, September 12, 2018 @ 16:41:03
  Author: heftig
Revision: 334420

archrelease: copy trunk to testing-x86_64

Added:
  vino/repos/testing-x86_64/
  vino/repos/testing-x86_64/PKGBUILD
    (from rev 334419, vino/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: vino/repos/testing-x86_64/PKGBUILD (from rev 334419, vino/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-09-12 16:41:03 UTC (rev 334420)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=vino
+pkgver=3.22.0+19+g15eb3c5
+pkgrel=1
+pkgdesc="A VNC server for the GNOME desktop"
+url="https://wiki.gnome.org/Projects/Vino"
+arch=(x86_64)
+license=(GPL)
+depends=(libnotify libxtst libsm telepathy-glib gtk3 libsecret avahi gnutls)
+makedepends=(intltool networkmanager gnome-common git)
+groups=(gnome)
+_commit=15eb3c5e51b799aa22fff547dd88921d9cc4b5f2  # master
+source=("git+https://gitlab.gnome.org/GNOME/vino.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --libexecdir=/usr/lib/vino \
+      --localstatedir=/var \
+      --disable-http-server --with-secret
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}