[arch-commits] Commit in haskell-aeson/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Sep 13 13:33:15 UTC 2018


    Date: Thursday, September 13, 2018 @ 13:33:15
  Author: felixonmars
Revision: 380194

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-aeson/repos/community-staging-x86_64/
  haskell-aeson/repos/community-staging-x86_64/PKGBUILD
    (from rev 380193, haskell-aeson/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-aeson/repos/community-staging-x86_64/PKGBUILD (from rev 380193, haskell-aeson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-13 13:33:15 UTC (rev 380194)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+pkgname=haskell-aeson
+_hkgname=aeson
+pkgver=1.4.0.0
+pkgrel=5
+pkgdesc="A JSON parsing and encoding library optimized for ease of use and high performance."
+url="https://github.com/bos/aeson"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-compat' 'haskell-dlist' 'haskell-hashable'
+         'haskell-scientific' 'haskell-tagged' 'haskell-th-abstraction' 'haskell-time-locale-compat'
+         'haskell-unordered-containers' 'haskell-uuid-types' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-integer-logarithms'
+             'haskell-base-orphans' 'haskell-base16-bytestring' 'haskell-generic-deriving'
+             'haskell-hashable-time' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
+sha512sums=('ebda273ed445c498ec58850fafaafaef3caf65d31939909377a9add638bb5f8a95a22121250019df2036c8552b7abdbb84a7d4ed7c6b9ab39ac4e1e89c741874')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  sed -i 's/<.*0.8/<1/' $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-developer -f-fast -f-bytestring-builder -f-cffi
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  runhaskell Setup copy --destdir="$pkgdir"
+  rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
+}



More information about the arch-commits mailing list