[arch-commits] Commit in libextractor/repos (2 files)

[Maxime Gauduin]

    Date: Thursday, September 13, 2018 @ 15:43:36
  Author: alucryd
Revision: 380321

archrelease: copy trunk to community-staging-x86_64

Added:
  libextractor/repos/community-staging-x86_64/
  libextractor/repos/community-staging-x86_64/PKGBUILD
    (from rev 380320, libextractor/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: libextractor/repos/community-staging-x86_64/PKGBUILD (from rev 380320, libextractor/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-13 15:43:36 UTC (rev 380321)
@@ -0,0 +1,45 @@
+# Maintainer: Sergej Pupykin <pupykin.s at gmail.com>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=libextractor
+pkgver=1.7
+pkgrel=2
+pkgdesc="A library used to extract meta-data from files of arbitrary type"
+arch=("x86_64")
+license=('GPL')
+url="http://gnunet.org/libextractor/"
+depends=('libltdl')
+makedepends=('exiv2' 'ffmpeg' 'file' 'flac' 'gst-plugins-base-libs' 'libgsf' 'libmpeg2' 'libvorbis' 'poppler')
+optdepends=('exiv2: metadata support'
+            'ffmpeg: previewopus/thumbnailffmpeg support'
+            'file: mime support'
+            'flac: flac support'
+            'gst-plugins-base-libs: gstreamer support'
+            'libarchive: archive support'
+            'libgsf: (optional) for ODF support'
+            'libmpeg2: mpeg support'
+            'libvorbis: ogg/vorbis support'
+            'poppler: pdf support')
+validpgpkeys=('19647543F7861D3BF4E64FF7BF60708B48426C7E'
+              'D8423BCB326C7907033929C7939E6BE1E29FC3CC')
+source=("https://ftp.gnu.org/gnu/libextractor/${pkgname}-${pkgver}.tar.gz"{,.sig})
+sha512sums=('00340af0987f58c16824f50a18484e76f110fa2b4a43788b950ea4313e6916b94d5e7f16e1f21c8a54509885d9b44dabdc5be7727547549836ddd8ca7251dbff'
+            'SKIP')
+
+prepare() {
+  sed -e 's/ CODEC_FLAG_QSCALE/ AV_CODEC_FLAG_QSCALE/' \
+      -e 's/FF_INPUT_BUFFER_PADDING_SIZE/AV_INPUT_BUFFER_PADDING_SIZE/' \
+      -i $pkgname-$pkgver/src/plugins/thumbnailffmpeg_extractor.c
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --enable-shared --disable-static
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir"/usr/share/info/dir
+}