[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, September 14, 2018 @ 17:07:12
  Author: felixonmars
Revision: 380930

addpkg: haskell-th-desugar 1.8-1

Added:
  haskell-th-desugar/
  haskell-th-desugar/repos/
  haskell-th-desugar/trunk/
  haskell-th-desugar/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-th-desugar/trunk/PKGBUILD
===================================================================
--- haskell-th-desugar/trunk/PKGBUILD	                        (rev 0)
+++ haskell-th-desugar/trunk/PKGBUILD	2018-09-14 17:07:12 UTC (rev 380930)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=th-desugar
+pkgname=haskell-th-desugar
+pkgver=1.8
+pkgrel=1
+pkgdesc="Functions to desugar Template Haskell"
+url="https://github.com/goldfirere/th-desugar"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-syb' 'haskell-th-lift' 'haskell-th-orphans' 'haskell-th-expand-syns')
+makedepends=('ghc' 'haskell-hunit' 'haskell-hspec')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('485bada31cc16ed41e7f867d4fbd519e926d6053e56926478e25ed7be4a5c561f21c350c07727c794c3480404650637be9015268853bc45c017692ced6a2be5f')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}