[arch-commits] Commit in (sdcc sdcc/repos sdcc/trunk sdcc/trunk/PKGBUILD)
Kyle Keen
kkeen at archlinux.org
Sat Sep 15 02:37:18 UTC 2018
Date: Saturday, September 15, 2018 @ 02:37:17
Author: kkeen
Revision: 381005
sdcc 3.7.0-5
Added:
sdcc/
sdcc/repos/
sdcc/trunk/
sdcc/trunk/PKGBUILD
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Added: sdcc/trunk/PKGBUILD
===================================================================
--- sdcc/trunk/PKGBUILD (rev 0)
+++ sdcc/trunk/PKGBUILD 2018-09-15 02:37:17 UTC (rev 381005)
@@ -0,0 +1,47 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Jose Negron <josenj.arch at mailnull.net>
+
+pkgname=sdcc
+pkgver=3.7.0
+pkgrel=5
+pkgdesc="Retargettable ANSI C compiler (Intel 8051, Maxim 80DS390, Zilog Z80 and the Motorola 68HC08)"
+arch=('x86_64')
+license=('GPL')
+depends=('bash' 'gcc-libs' 'boost-libs')
+makedepends=('gputils' 'flex' 'bison' 'patch' 'boost')
+optdepends=('python')
+url="http://sdcc.sourceforge.net/"
+options=(!strip staticlibs)
+source=(https://downloads.sourceforge.net/sourceforge/sdcc/$pkgname-src-${pkgver//_/-}.tar.bz2)
+md5sums=('76cc85d7ff27c46b930d309ea940a02f')
+
+# namcap claims boost-libs isn't needed, investigate this
+
+prepare() {
+ cd "$srcdir/$pkgname"
+ sed -i 's|CC -E|CC -O2 -E|g' support/sdbinutils/libiberty/configure
+}
+
+build() {
+ cd "$srcdir/$pkgname"
+ ./configure \
+ --prefix=/usr \
+ --includedir=/usr/include/sdcc \
+ --libdir=/usr/lib/sdcc \
+ --disable-werror
+ make
+}
+
+package() {
+ cd "$srcdir/$pkgname"
+
+ make install DESTDIR="$pkgdir"
+
+ if [ -d "$pkgdir/usr/lib/lib" ]; then
+ mv "$pkgdir/usr/lib/lib/"* "$pkgdir/usr/lib/sdcc/"
+ rm -rf "$pkgdir/usr/lib/lib"
+ fi
+
+ sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python3|' "$pkgdir/usr/bin/as2gbmap"
+}
More information about the arch-commits
mailing list