[arch-commits] Commit in haskell-shakespeare/repos (2 files)

[Felix Yan]

    Date: Saturday, September 15, 2018 @ 07:50:27
  Author: felixonmars
Revision: 381320

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-shakespeare/repos/community-staging-x86_64/
  haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD
    (from rev 381319, haskell-shakespeare/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD (from rev 381319, haskell-shakespeare/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-15 07:50:27 UTC (rev 381320)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=shakespeare
+pkgname=haskell-shakespeare
+pkgver=2.0.17
+pkgrel=3
+pkgdesc="A toolkit for making compile-time interpolated templates"
+url="http://www.yesodweb.com/book/shakespearean-templates"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-exceptions'
+         'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('d8e6e67ef2d316bcc81efe89778d6de0a26f6489791debe62841dc46832d15a201e9ccc51bfa1a5b97da63b00f99e336998511a86a0606ceda05118d7ecfbfaa')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-test_roy -f-test_coffee -f-test_export
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}