[arch-commits] Commit in gnome-remote-desktop/trunk (PKGBUILD)
Jan Steffens
heftig at archlinux.org
Tue Sep 18 16:23:09 UTC 2018
Date: Tuesday, September 18, 2018 @ 16:23:08
Author: heftig
Revision: 334887
0.1.6-1
Added:
gnome-remote-desktop/trunk/PKGBUILD
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-09-18 16:23:08 UTC (rev 334887)
@@ -0,0 +1,38 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-remote-desktop
+pkgver=0.1.6
+pkgrel=1
+pkgdesc="GNOME Remote Desktop server"
+url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
+arch=(x86_64)
+license=(GPL2)
+depends=(glib2 pipewire systemd libvncserver libsecret libnotify dconf)
+makedepends=(git meson)
+groups=(gnome)
+_commit=81ae42ee570fe44ce6a6ba89f671b587a2d22c54 # tags/0.1.6^0
+source=("git+https://gitlab.gnome.org/jadahl/gnome-remote-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ sed -i 's|pipewire-0\.1|pipewire-0.2|g' meson.build
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
Property changes on: gnome-remote-desktop/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list