[arch-commits] Commit in haskell-servant/repos (2 files)

[Felix Yan]

    Date: Friday, September 28, 2018 @ 09:38:32
  Author: felixonmars
Revision: 387120

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant/repos/community-staging-x86_64/
  haskell-servant/repos/community-staging-x86_64/PKGBUILD
    (from rev 387119, haskell-servant/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-servant/repos/community-staging-x86_64/PKGBUILD (from rev 387119, haskell-servant/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-28 09:38:32 UTC (rev 387120)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant
+pkgname=haskell-servant
+pkgver=0.13.0.1
+pkgrel=41
+pkgdesc="A family of combinators for defining webservices APIs"
+url="http://haskell-servant.readthedocs.org/"
+license=("custom:BSD3")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-case-insensitive' 'haskell-http-api-data' 'haskell-http-media'
+         'haskell-http-types' 'haskell-natural-transformation' 'haskell-mmorph'
+         'haskell-tagged' 'haskell-singleton-bool' 'haskell-string-conversions'
+         'haskell-network-uri' 'haskell-vault')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-aeson-compat' 'haskell-hspec'
+             'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3be9a97f2cc3d60cf3fc0f09aa3ee227f777dcb7e85e8579b1c169319f03dbb742fafa7dd1d4a1d20cdd04534cd327af3cbb04daf684ebdfc4e6e3a8c7b819d6')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e 's/<.*0.16/<1/' -e 's/<.*1.4/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}