[arch-commits] Commit in haskell-yesod-persistent/repos (2 files)

[Felix Yan]

    Date: Friday, September 28, 2018 @ 18:03:49
  Author: felixonmars
Revision: 387457

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-persistent/repos/community-staging-x86_64/
  haskell-yesod-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 387456, haskell-yesod-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-yesod-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 387456, haskell-yesod-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-09-28 18:03:49 UTC (rev 387457)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-persistent
+pkgname=haskell-yesod-persistent
+pkgver=1.6.0
+pkgrel=117
+pkgdesc="Some helpers for using Persistent from Yesod."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-blaze-builder" "haskell-conduit" "haskell-persistent"
+         "haskell-persistent-template" "haskell-resource-pool" "haskell-resourcet"
+         "haskell-yesod-core")
+makedepends=('ghc' 'haskell-hspec' 'haskell-wai-extra' 'haskell-persistent-sqlite')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('8000d9f9a3406aff157652989946b915ba54e4241e59afc29c51c647f5c45d05cad7d46a92423fa3811a9a6238f6a4a759320309b337d369346fe5470d927982')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}