[arch-commits] Commit in haskell-http2/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Apr 2 01:43:16 UTC 2019


    Date: Tuesday, April 2, 2019 @ 01:43:16
  Author: felixonmars
Revision: 447401

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http2/repos/community-staging-x86_64/
  haskell-http2/repos/community-staging-x86_64/PKGBUILD
    (from rev 447400, haskell-http2/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-http2/repos/community-staging-x86_64/PKGBUILD (from rev 447400, haskell-http2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-02 01:43:16 UTC (rev 447401)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http2
+pkgname=haskell-http2
+pkgver=1.6.4
+pkgrel=21
+pkgdesc="HTTP/2.0 library including frames and HPACK"
+url="https://github.com/kazu-yamamoto/http2"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-case-insensitive' 'haskell-network-byte-order' 'haskell-psqueues')
+makedepends=('ghc' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-doctest' 'haskell-glob'
+             'haskell-hex' 'haskell-hspec' 'haskell-word8' 'haskell-unordered-containers'
+             'haskell-vector')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('f637597827abae4968f9af69a190432af6bc37b6ecf2420766341e4739cab558c20b43aecf0eb4be1ef8a8b05f3d75dfc56243ec65c0b842cba542df7d5ab8d9')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-devel
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list