[arch-commits] Commit in radare2/repos (2 files)

Levente Polyak anthraxx at archlinux.org
Thu Apr 4 12:10:21 UTC 2019


    Date: Thursday, April 4, 2019 @ 12:10:20
  Author: anthraxx
Revision: 449137

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2/repos/community-staging-x86_64/
  radare2/repos/community-staging-x86_64/PKGBUILD
    (from rev 449136, radare2/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: radare2/repos/community-staging-x86_64/PKGBUILD (from rev 449136, radare2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-04 12:10:20 UTC (rev 449137)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Guillermo Ramos <0xwille at gmail dot com>
+
+pkgname=radare2
+pkgver=3.4.1
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://radare.org'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=('sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib'
+         'lz4' 'xxhash' 'libxxhash.so' 'file' 'libuv')
+makedepends=('meson')
+options=('!emptydirs')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/radare/radare2/archive/${pkgver}.tar.gz)
+sha256sums=('3df1f9a79ef64f9c9205453c735ac5a29ef8e88f336fd16c5bbaa64b1dc0c975')
+sha512sums=('8803d54a8158aedd5900792bd013dad440a14abbb6fcbdf963e5d9031f30e66865479f29877e6f656ab01b59b3138458daf52f1eaeb462ec767c128d0b12640a')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  touch libr/config.mk
+  arch-meson build \
+    -D use_sys_capstone=true \
+    -D use_sys_magic=true \
+    -D use_sys_zip=true \
+    -D use_sys_zlib=true \
+    -D use_sys_lz4=true \
+    -D use_sys_xxhash=true \
+    -D use_sys_openssl=true \
+    -D use_libuv=true \
+    -D use_webui=true
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
+  ln -s /usr/bin/radare2 "${pkgdir}/usr/bin/r2"
+  ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list