[arch-commits] Commit in webkit2gtk/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Fri Apr 5 12:39:35 UTC 2019
Date: Friday, April 5, 2019 @ 12:39:34
Author: felixonmars
Revision: 349884
archrelease: copy trunk to staging-x86_64
Added:
webkit2gtk/repos/staging-x86_64/
webkit2gtk/repos/staging-x86_64/PKGBUILD
(from rev 349883, webkit2gtk/trunk/PKGBUILD)
----------+
PKGBUILD | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 58 insertions(+)
Copied: webkit2gtk/repos/staging-x86_64/PKGBUILD (from rev 349883, webkit2gtk/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2019-04-05 12:39:34 UTC (rev 349884)
@@ -0,0 +1,58 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=webkit2gtk
+pkgver=2.24.0
+pkgrel=2
+pkgdesc="GTK+ Web content engine library"
+arch=(x86_64)
+url="https://webkitgtk.org/"
+license=(custom)
+depends=(libxt libxslt enchant gst-plugins-base-libs libsecret libwebp openjpeg2
+ harfbuzz-icu gtk3 libnotify hyphen woff2)
+makedepends=(gperf gobject-introspection ruby gtk-doc cmake python geoclue)
+optdepends=('geoclue: Geolocation support'
+ 'gst-plugins-good: media decoding'
+ 'gst-plugins-bad: media decoding'
+ 'gst-libav: nonfree media decoding')
+source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
+sha256sums=('2e4ad1503fe482ceb5a83cf70ac9cd42f37eb718555a4d6844fe4c59a9214407'
+ 'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'
+ '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')
+
+prepare() {
+ cd webkitgtk-$pkgver
+}
+
+build() {
+ cmake -Hwebkitgtk-$pkgver -Bbuild \
+ -DPORT=GTK \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DENABLE_GTKDOC=ON \
+ -DENABLE_PLUGIN_PROCESS_GTK2=OFF \
+ -DLIBEXEC_INSTALL_DIR=/usr/lib \
+ -DLIB_INSTALL_DIR=/usr/lib
+ cmake --build build
+}
+
+check() {
+ : cmake --build build --target tests
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --build build --target install
+
+ cd webkitgtk-$pkgver
+ find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+ while IFS= read -d $'\0' -r _f; do
+ echo "### $_f ###"
+ cat "$_f"
+ echo
+ done |
+ install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list