[arch-commits] Commit in gnucash/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Apr 5 13:24:01 UTC 2019


    Date: Friday, April 5, 2019 @ 13:24:00
  Author: felixonmars
Revision: 449804

archrelease: copy trunk to community-staging-x86_64

Added:
  gnucash/repos/community-staging-x86_64/
  gnucash/repos/community-staging-x86_64/PKGBUILD
    (from rev 449803, gnucash/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gnucash/repos/community-staging-x86_64/PKGBUILD (from rev 449803, gnucash/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-05 13:24:00 UTC (rev 449804)
@@ -0,0 +1,49 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Mark Schneider <queueRAM at gmail.com>
+
+pkgname=gnucash
+pkgver=3.4
+pkgrel=4
+pkgdesc='Personal and small-business financial-accounting application'
+arch=(x86_64)
+url='https://gnucash.org/'
+license=(GPL)
+depends=(aqbanking boost-libs guile libdbi webkit2gtk)
+makedepends=(boost cmake gmock libdbi-drivers mariadb-libs postgresql-libs)
+optdepends=('gnucash-docs: documentation'
+            'libdbi-drivers: open and save data into SQL database'
+            'perl-date-manip: stock information lookups'
+            'perl-finance-quote: stock information lookups')
+options=(!emptydirs)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz)
+sha256sums=('95e8d340b7299e67ed9bedd29141cdc50824a1d6c17ebba302396b862e33b2ea')
+
+build() {
+  cd $pkgname-$pkgver
+
+  # Do not treat warnings as errors
+  sed -e 's|-Werror||g' -i CMakeLists.txt
+
+  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DWITH_PYTHON=ON \
+        -DHAVE_GWEN_GTK3=ON \
+        -DCOMPILE_GSCHEMAS=OFF
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make -k check || : # 2 tests failed
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # Delete the gnucash-valgrind executable because the source files
+  # are not included with the package and the executable is hardlinked
+  # to the location that it was built at.
+  rm -f "$pkgdir/usr/bin/gnucash-valgrind"
+}


More information about the arch-commits mailing list