[arch-commits] Commit in tp_smapi-lts/repos (2 files)

Andreas Radke andyrtr at archlinux.org
Sat Apr 6 18:41:09 UTC 2019


    Date: Saturday, April 6, 2019 @ 18:41:09
  Author: andyrtr
Revision: 450016

archrelease: copy trunk to community-testing-x86_64

Added:
  tp_smapi-lts/repos/community-testing-x86_64/
  tp_smapi-lts/repos/community-testing-x86_64/PKGBUILD
    (from rev 450015, tp_smapi-lts/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: tp_smapi-lts/repos/community-testing-x86_64/PKGBUILD (from rev 450015, tp_smapi-lts/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-04-06 18:41:09 UTC (rev 450016)
@@ -0,0 +1,50 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: xduugu
+# Contributor: nh2
+# Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
+# Contributor: Nick B <Shirakawasuna ð gmail đ com>
+# Contributor: Christof Musik <christof ð senfdax đ de>
+# Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
+# Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
+
+pkgname=tp_smapi-lts
+_pkgname=tp-smapi
+pkgver=0.43
+_extradir=/usr/lib/modules/extramodules-4.19-lts
+pkgrel=1
+pkgdesc="Modules for ThinkPad's SMAPI functionality"
+arch=('x86_64')
+url='https://github.com/evgeni/tp_smapi'
+license=('GPL')
+depends=('linux-lts>=4.19.34' 'linux-lts<4.20')
+makedepends=('linux-lts-headers>=4.19.34' 'linux-lts-headers<4.20' 'git')
+_commit=a63729ab30d85430048f65c37f29188ab484cd52  # tags/tp-smapi/0.43
+source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname/-lts/}
+  git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
+}
+
+build() {
+  cd ${pkgname/-lts/}
+
+  # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
+  # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
+
+  make HDAPS=1 KVER="$(<$_extradir/version)" EXTRA_CFLAGS=
+}
+
+package() {
+  cd ${pkgname/-lts/}
+
+  # install kernel modules
+  find . -name "*.ko" -exec install -Dt "$pkgdir$_extradir" {} +
+
+  # compress kernel modules
+  find "$pkgdir" -name "*.ko" -exec gzip -n -9 {} +
+
+  # load module on startup
+  echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
+}



More information about the arch-commits mailing list