[arch-commits] Commit in fzf/trunk (PKGBUILD)

[Filipe Laíns]

    Date: Thursday, April 11, 2019 @ 09:21:54
  Author: ffy00
Revision: 451023

upgpkg: fzf 0.18.0-1

Use go mod instead of glide (no more $GOPATH!)
Refactor PKGBUILD to make the style consistent (feel free to change it if you don't like my style, just try to keep it consistent)

Modified:
  fzf/trunk/PKGBUILD

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++----------------------------------
 1 file changed, 29 insertions(+), 36 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2019-04-11 09:02:25 UTC (rev 451022)
+++ PKGBUILD	2019-04-11 09:21:54 UTC (rev 451023)
@@ -1,5 +1,6 @@
 # Maintainer: Thore Bödecker <foxxx0 at archlinux.org>
 # Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
 # Contributor: Pierre Neidhardt <ambrevar at gmail.com>
 # Contributor: Hermann Zahnweh (eigengrau)
 # Contributor: Andy Weidenbaum <archbaum at gmail.com>
@@ -7,63 +8,55 @@
 # Contributor: jebaum <jebaum at ucla dot edu>
 
 pkgname=fzf
-pkgver=0.17.5
+pkgver=0.18.0
 pkgrel=1
-pkgdesc="Command-line fuzzy finder"
-arch=("x86_64")
-url="https://github.com/junegunn/fzf"
-license=("MIT")
-depends=("bash")
-makedepends=("git" "go-pie" "glide")
-optdepends=("fish: fish keybindings"
-	"tmux: fzf-tmux script for launching fzf in a tmux pane"
-	"vim: plugin"
-	"zsh: zsh keybindings")
-source=("${pkgname}-${pkgver}.tar.gz::https://github.com/junegunn/fzf/archive/${pkgver}.tar.gz"
-	"git+https://github.com/junegunn/${pkgname}.wiki")
-sha256sums=('de3b39758e01b19bbc04ee0d5107e14052d3a32ce8f40d4a63d0ed311394f7ee'
+pkgdesc='Command-line fuzzy finder'
+arch=('x86_64')
+url='https://github.com/junegunn/fzf'
+license=('MIT')
+depends=('bash')
+makedepends=('git' 'go-pie')
+optdepends=('fish: fish keybindings'
+            'tmux: fzf-tmux script for launching fzf in a tmux pane'
+            'vim: plugin'
+            'zsh: zsh keybindings')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
+        "git+$url.wiki")
+sha512sums=('70dcda693ed6706f232874550f89cfcdbce1d28360244a728dd0640a4cfbbbd0899601f42c9096197c159cde86e89d287a06905cb5d665bd09b9d01cca2cb754'
             'SKIP')
 
+build() {
+	cd $pkgname-$pkgver
 
-prepare(){
-	export GOPATH="$srcdir/go"
-	mkdir -p $GOPATH/src/github.com/junegunn
-	ln -rTsf "${srcdir}/${pkgname}-${pkgver}" $GOPATH/src/github.com/junegunn/fzf
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	glide up
-}
-
-build() {
-	export GOPATH="$srcdir/go"
-	cd "${srcdir}/${pkgname}-${pkgver}"
 	go build -o fzf .
 }
 
 package() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
+	cd $pkgname-$pkgver
 
 	## Doc
-	install -dm755 "$pkgdir/usr/share/doc/fzf/wiki"
-	install -m644 "$srcdir/fzf.wiki"/* "$pkgdir/usr/share/doc/fzf/wiki"
-	install -m644 README.md "$pkgdir/usr/share/doc/fzf"
+	install -dm755 "$pkgdir"/usr/share/doc/fzf/wiki
+	install -m644 "$srcdir"/fzf.wiki/* "$pkgdir"/usr/share/doc/fzf/wiki
+	install -m644 README.md "$pkgdir"/usr/share/doc/fzf
 
 	## Man page
-	install -Dm644 "man/man1/fzf.1" "$pkgdir/usr/share/man/man1/fzf.1"
+	install -Dm644 man/man1/fzf.1 "$pkgdir"/usr/share/man/man1/fzf.1
 
 	## License
-	install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/fzf/LICENSE"
+	install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/fzf/LICENSE
 
 	## Binaries
-	install -dm755 "$pkgdir/usr/bin"
-	install -m755 "fzf" "bin/fzf-tmux" "$pkgdir/usr/bin/"
+	install -dm755 "$pkgdir"/usr/bin
+	install -m755 fzf bin/fzf-tmux "$pkgdir"/usr/bin/
 
 	## Completion and keybindings
-	install -dm755 "$pkgdir/usr/share/fzf"
-	install -m644 shell/*.bash shell/*.zsh "$pkgdir/usr/share/fzf"
+	install -dm755 "$pkgdir"/usr/share/fzf
+	install -m644 shell/*.bash shell/*.zsh "$pkgdir"/usr/share/fzf
 
 	## Fish keybindings
-	install -Dm644 "shell/key-bindings.fish" "$pkgdir/usr/share/fish/functions/fzf_key_bindings.fish"
+	install -Dm644 shell/key-bindings.fish "$pkgdir"/usr/share/fish/functions/fzf_key_bindings.fish
 
 	## Vim plugin
 	install -Dm644 plugin/fzf.vim "$pkgdir"/usr/share/vim/vimfiles/plugin/fzf.vim
 }
+