[arch-commits] Commit in oxygen-icons/repos (testing-any testing-any/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Sat Apr 13 07:29:36 UTC 2019


    Date: Saturday, April 13, 2019 @ 07:29:35
  Author: arojas
Revision: 350760

archrelease: copy trunk to testing-any

Added:
  oxygen-icons/repos/testing-any/
  oxygen-icons/repos/testing-any/PKGBUILD
    (from rev 350759, oxygen-icons/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: oxygen-icons/repos/testing-any/PKGBUILD (from rev 350759, oxygen-icons/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2019-04-13 07:29:35 UTC (rev 350760)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=oxygen-icons
+pkgname=(oxygen-icons oxygen-icons-svg)
+pkgver=5.57.0
+epoch=1
+pkgrel=1
+pkgdesc="The Oxygen Icon Theme"
+arch=(any)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+makedepends=(extra-cmake-modules qt5-base)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgbase}5-$pkgver.tar.xz"{,.sig})
+sha256sums=('2b12a9de3767d233b4b01bc97e23899d94c02b13fee4d20483d3f5d2baaaa1e5'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../${pkgbase}5-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package_oxygen-icons() {
+  groups=(kf5)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+}
+
+package_oxygen-icons-svg() {
+  pkgdesc="The Oxygen Icon Theme (Scalable Vector Graphics)"
+
+  cd ${pkgbase}5-$pkgver
+  find scalable -type f ! -name '*.sh' -exec \
+    install -D -m644 "{}" "$pkgdir"/usr/share/icons/oxygen/{} \;
+}


More information about the arch-commits mailing list