[arch-commits] Commit in (4 files)

[Maxim Baz]

    Date: Saturday, April 13, 2019 @ 09:02:29
  Author: maximbaz
Revision: 451387

browserpass: new pkg

Added:
  browserpass/
  browserpass/repos/
  browserpass/trunk/
  browserpass/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: browserpass/trunk/PKGBUILD
===================================================================
--- browserpass/trunk/PKGBUILD	                        (rev 0)
+++ browserpass/trunk/PKGBUILD	2019-04-13 09:02:29 UTC (rev 451387)
@@ -0,0 +1,42 @@
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+# Contributor: emersion <contact emersion.fr>
+
+_name=browserpass-native
+pkgname=browserpass
+pkgver=3.0.6
+pkgrel=1
+pkgdesc="Native host app for Browserpass, browser extension for zx2c4's pass (password manager)"
+arch=('x86_64')
+url="https://github.com/${pkgname}/${_name}"
+license=('ISC')
+depends=('gnupg')
+makedepends=('go-pie' 'git')
+optdepends=('browserpass-chromium: Chromium extension for Browserpass'
+            'browserpass-firefox: Firefox extension for Browserpass')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
+        "${pkgname}-${pkgver}.tar.gz.asc::${url}/releases/download/${pkgver}/${_name}-${pkgver}.tar.gz.asc")
+sha256sums=('6a2442192aad8fae3642b925d1ff04368eef3a390043e6164c8eb2fd2a438ceb'
+            'SKIP')
+validpgpkeys=('EB4F9E5A60D32232BB52150C12C87A28FEAC6B20')
+
+prepare() {
+    cd "${_name}-${pkgver}"
+    make configure
+}
+
+build() {
+    cd "${_name}-${pkgver}"
+    make "${pkgname}"
+}
+
+check() {
+    cd "${_name}-${pkgver}"
+    make test
+}
+
+package() {
+    cd "${_name}-${pkgver}"
+    make DESTDIR="${pkgdir}" install
+}
+
+# vim:set ts=4 sw=4 et: