[arch-commits] Commit in rtmidi/repos (2 files)

David Runge dvzrv at archlinux.org
Thu Apr 18 16:53:43 UTC 2019


    Date: Thursday, April 18, 2019 @ 16:53:42
  Author: dvzrv
Revision: 451993

archrelease: copy trunk to community-staging-x86_64

Added:
  rtmidi/repos/community-staging-x86_64/
  rtmidi/repos/community-staging-x86_64/PKGBUILD
    (from rev 451992, rtmidi/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: rtmidi/repos/community-staging-x86_64/PKGBUILD (from rev 451992, rtmidi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-18 16:53:42 UTC (rev 451993)
@@ -0,0 +1,47 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
+# Contributor: rtfreedman  <rob dot til dot freedman at gmail dot com>
+# Contributor: speps <speps at aur dot archlinux dot org> 
+
+pkgname=rtmidi
+pkgver=4.0.0
+pkgrel=1
+pkgdesc="A set of C++ classes that provides a common API for realtime MIDI input/output."
+arch=('x86_64')
+url="https://www.music.mcgill.ca/~gary/rtmidi/"
+license=('custom:MIT')
+depends=('jack')
+makedepends=('doxygen')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/thestk/${pkgname}/archive/${pkgver}.tar.gz")
+sha512sums=('39383f121320c9471b31f8b9d283167bfadf4c7328b6664d1d54a4c52e3dd9b76362875258d90363c6044e87fcee31ccce80e19435dc620c88e6d60fc82d0f9d')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  autoreconf -fi
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  ./configure --prefix=/usr \
+              --with-alsa \
+              --with-jack
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  # docs
+  install -t "${pkgdir}/usr/share/doc/${pkgname}" \
+    -vDm 644 {README.md,doc/release.txt}
+  # html
+  install -vDm 644 doc/html/* \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/html"
+  install -vDm 644 doc/images/* \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/images"
+  # license in README.md:
+  # https://github.com/thestk/rtmidi/issues/198
+  csplit -s README.md "%Legal and%"
+  install -vDm 644 xx00 "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+


More information about the arch-commits mailing list