[arch-commits] Commit in stk/repos (2 files)

[David Runge]

    Date: Thursday, April 18, 2019 @ 19:56:10
  Author: dvzrv
Revision: 451995

archrelease: copy trunk to community-staging-x86_64

Added:
  stk/repos/community-staging-x86_64/
  stk/repos/community-staging-x86_64/PKGBUILD
    (from rev 451994, stk/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: stk/repos/community-staging-x86_64/PKGBUILD (from rev 451994, stk/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-18 19:56:10 UTC (rev 451995)
@@ -0,0 +1,58 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Mateusz Herych <heniekk at gmail.com>
+
+pkgname=stk
+# CAUTION: introduces soname change on *every* release:
+# https://github.com/thestk/stk/issues/89
+pkgver=4.6.1
+pkgrel=1
+pkgdesc='The Synthesis ToolKit in C++'
+arch=('x86_64')
+url='https://ccrma.stanford.edu/software/stk/'
+license=('MIT')
+depends=('jack')
+makedepends=('doxygen')
+optdepends=('tk: run provided demos/samples')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/thestk/${pkgname}/archive/${pkgver}.tar.gz")
+sha512sums=('61d4db7b4a45446e231dedc13e139cb488e2ce805278f0b20aa95e69ddb1fa9be549ab5f1fe24c69aa865ebc2940d5fba6e3819a1a7fb1d68e236131fcfb4cac')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  autoreconf -vfi
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure RAWWAVE_PATH=/usr/share/${pkgname}/rawwaves/ \
+              --prefix=/usr \
+              --enable-shared \
+              --with-alsa \
+              --with-jack
+  make
+  make -C projects/demo
+  cd doc/doxygen
+  doxygen
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make DESTDIR="${pkgdir}" install
+  # demo
+  install -vDm 755 projects/demo/stk-demo -t "${pkgdir}/usr/bin"
+  install -vDm 644 projects/demo/tcl/*.tcl \
+    -t "${pkgdir}/usr/share/${pkgname}/tcl"
+  install -vDm 644 projects/demo/scores/{README,*.ski} \
+    -t "${pkgdir}/usr/share/${pkgname}/scores"
+  install -vDm 644 rawwaves/*.{raw,c} \
+    -t "${pkgdir}/usr/share/${pkgname}/rawwaves"
+  # docs
+  install -vDm 644 doc/{README-Linux,ReleaseNotes,SKINI,hierarchy}.txt \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 doc/html/*.{html,png,js} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/html"
+  # license
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname}"
+}