[arch-commits] Commit in kig/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Sat Apr 20 16:27:12 UTC 2019


    Date: Saturday, April 20, 2019 @ 16:27:11
  Author: arojas
Revision: 351041

archrelease: copy trunk to testing-x86_64

Added:
  kig/repos/testing-x86_64/
  kig/repos/testing-x86_64/PKGBUILD
    (from rev 351040, kig/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: kig/repos/testing-x86_64/PKGBUILD (from rev 351040, kig/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-04-20 16:27:11 UTC (rev 351041)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kig
+pkgver=19.04.0
+pkgrel=1
+pkgdesc="Interactive Geometry"
+url="https://kde.org/applications/education/kig/"
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdeedu)
+depends=(ktexteditor qt5-xmlpatterns boost-libs python2 hicolor-icon-theme)
+makedepends=(extra-cmake-modules kdoctools boost)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('781243a23a94d7a9882bd69ddfcd74a5b9df0ce28cd45488e62dcf54e3633234'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DBUILD_TESTING=OFF \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # Use the python2 executable
+  sed -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' -i "$pkgdir"/usr/bin/pykig.py
+}


More information about the arch-commits mailing list