[arch-commits] Commit in hugin/repos (2 files)

Bruno Pagani archange at archlinux.org
Mon Apr 22 14:15:48 UTC 2019


    Date: Monday, April 22, 2019 @ 14:15:47
  Author: archange
Revision: 452962

archrelease: copy trunk to community-testing-x86_64

Added:
  hugin/repos/community-testing-x86_64/
  hugin/repos/community-testing-x86_64/PKGBUILD
    (from rev 452961, hugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: hugin/repos/community-testing-x86_64/PKGBUILD (from rev 452961, hugin/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-04-22 14:15:47 UTC (rev 452962)
@@ -0,0 +1,42 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Dominik Ryba <domryba at post.pl>
+
+pkgname=hugin
+pkgver=2019.0.0
+pkgrel=1
+pkgdesc="Panorama photo stitcher"
+arch=(x86_64)
+url="http://hugin.sourceforge.net/"
+license=(GPL)
+depends=(wxgtk3 boost-libs libtiff libpano13 libjpeg libpng openexr vigra
+         exiv2 glew sqlite lcms2 lapack fftw glu libxi libxmu python
+         lensfun make enblend-enfuse)
+makedepends=(cmake boost tclap mesa swig)
+optdepends=('perl-image-exiftool: GPano tags support'
+            'dcraw: RAW import using dcraw'
+            'darktable: RAW import using darktable'
+            'rawtherapee: RAW import using rawtherapee')
+source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver/r/_r}.tar.bz2")
+sha256sums=('f94717c5035b776a552163bac5815916e0662008fabefafd790fa54b352e22d1')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    cmake ../${pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DENABLE_LAPACK=yes \
+        -DBUILD_HSI=ON \
+        -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3
+    make
+}
+
+package() {
+    cd build
+    make DESTDIR="${pkgdir}" install
+}


More information about the arch-commits mailing list