[arch-commits] Commit in gst-plugins-base/repos (2 files)
Jan Steffens
heftig at archlinux.org
Mon Apr 22 21:02:15 UTC 2019
Date: Monday, April 22, 2019 @ 21:02:14
Author: heftig
Revision: 351943
archrelease: copy trunk to testing-x86_64
Added:
gst-plugins-base/repos/testing-x86_64/
gst-plugins-base/repos/testing-x86_64/PKGBUILD
(from rev 351942, gst-plugins-base/trunk/PKGBUILD)
----------+
PKGBUILD | 68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 68 insertions(+)
Copied: gst-plugins-base/repos/testing-x86_64/PKGBUILD (from rev 351942, gst-plugins-base/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2019-04-22 21:02:14 UTC (rev 351943)
@@ -0,0 +1,68 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gst-plugins-base
+pkgname=(gst-plugins-base-libs gst-plugins-base)
+pkgver=1.16.0
+pkgrel=1
+pkgdesc="GStreamer open-source multimedia framework base plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gstreamer orc libxv iso-codes libgudev mesa)
+makedepends=(alsa-lib cdparanoia libvisual libvorbis libtheora pango opus graphene libpng libjpeg
+ gobject-introspection gtk-doc git meson)
+checkdepends=(gtk3 qt5-base clutter sdl glu xorg-server-xvfb)
+options=(!emptydirs)
+_commit=e0f8f635a96a3639be4d519fcf234b619bb74ca6 # tags/1.16.0^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-base.git#commit=$_commit"
+ "gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+
+ git submodule init
+ git config --local submodule.common.url "$srcdir/gst-common"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgbase build \
+ -D tremor=disabled \
+ -D package-name="GStreamer Base Plugins (Arch Linux)" \
+ -D package-origin="https://www.archlinux.org/"
+ ninja -C build
+}
+
+check() (
+ mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+ export XDG_RUNTIME_DIR
+
+ xvfb-run -s '+iglx -noreset' meson test -C build --print-errorlogs
+)
+
+package_gst-plugins-base-libs() {
+ pkgdesc="${pkgdesc/Plugins/Libraries}"
+
+ DESTDIR="$pkgdir" meson install -C build
+
+ mkdir -p ext/lib/gstreamer-1.0
+ for _x in alsa cdparanoia libvisual ogg opengl opus pango theora vorbis; do
+ _x="lib/gstreamer-1.0/libgst${_x}.so"
+ mv "$pkgdir/usr/$_x" "ext/$_x"
+ done
+}
+
+package_gst-plugins-base() {
+ depends=("gst-plugins-base-libs=$pkgver"
+ alsa-lib cdparanoia libvisual libvorbis libtheora pango opus graphene libpng libjpeg)
+
+ mv ext "$pkgdir/usr"
+}
More information about the arch-commits
mailing list