[arch-commits] Commit in haskell-warp/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Apr 29 14:13:39 UTC 2019


    Date: Monday, April 29, 2019 @ 14:13:38
  Author: felixonmars
Revision: 456197

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-warp/repos/community-staging-x86_64/
  haskell-warp/repos/community-staging-x86_64/PKGBUILD
    (from rev 456196, haskell-warp/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-warp/repos/community-staging-x86_64/PKGBUILD (from rev 456196, haskell-warp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-04-29 14:13:38 UTC (rev 456197)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=warp
+pkgname=haskell-warp
+pkgver=3.2.26
+pkgrel=29
+pkgdesc="A fast, light-weight web server for WAI applications."
+url="https://github.com/yesodweb/wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-auto-update' 'haskell-bsb-http-chunked'
+         'haskell-case-insensitive' 'haskell-hashable' 'haskell-http-date' 'haskell-http-types'
+         'haskell-http2' 'haskell-iproute' 'haskell-network' 'haskell-simple-sendfile'
+         'haskell-streaming-commons' 'haskell-unix-compat' 'haskell-vault'
+         'haskell-wai' 'haskell-word8')
+makedepends=('ghc' 'haskell-doctest' 'haskell-http-client' 'haskell-hspec' 'haskell-hunit'
+             'haskell-lifted-base' 'haskell-quickcheck' 'haskell-silently')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('62a27d759c9be75b9556a1a416b9a2643b8c75b43e3b8dd2519d9977c7d908ee2cc7c453f3a6e37a1e957f2f9b712c5b70a929e116d65730de835cd3983e9170')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-warp-debug -fallow-sendfilefd -f-network-bytestring
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list