[arch-commits] Commit in (4 files)

[David Runge]

    Date: Monday, April 29, 2019 @ 22:46:47
  Author: dvzrv
Revision: 456602

Adding php-imagick as optdepends to nextcloud (and probably several others).

Added:
  php-imagick/
  php-imagick/repos/
  php-imagick/trunk/
  php-imagick/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: php-imagick/trunk/PKGBUILD
===================================================================
--- php-imagick/trunk/PKGBUILD	                        (rev 0)
+++ php-imagick/trunk/PKGBUILD	2019-04-29 22:46:47 UTC (rev 456602)
@@ -0,0 +1,43 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+
+pkgname=php-imagick
+_name=imagick
+pkgver=3.4.3
+pkgrel=6
+pkgdesc="PHP extension to create and modify images using the ImageMagick library"
+arch=('x86_64')
+url="https://github.com/mkoppanen/imagick"
+license=('PHP')
+depends=('php' 'imagemagick')
+backup=("etc/php/conf.d/${_name}.ini")
+source=("$pkgname-$pkgver.tar.gz::https://github.com/mkoppanen/${_name}/archive/${pkgver}.tar.gz")
+sha512sums=('5a5b3954324dbd861ec36d52863ec88e7cf1127adb336c49ed4ce15a0e5683c2f99d977569f98e0143870f7494de8477422ee5e5ab1a6ede36bf36c3259df1e8')
+
+prepare() {
+  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  echo ";extension=${_name}" > "${_name}.ini"
+  phpize
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure --prefix=/usr
+  make
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  export NO_INTERACTION="true"
+  make -k test || msg "Known failing tests."
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make INSTALL_ROOT="$pkgdir/" install
+  install -vDm 644 "${_name}.ini" -t "${pkgdir}/etc/php/conf.d/"
+  install -vDm 644 {ChangeLog,CREDITS,README.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 examples/*.php \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+}