[arch-commits] Commit in (swig3 swig3/repos swig3/trunk swig3/trunk/PKGBUILD)

[Felix Yan]

    Date: Friday, August 2, 2019 @ 05:18:07
  Author: felixonmars
Revision: 496495

addpkg: swig3 3.0.12-1

Added:
  swig3/
  swig3/repos/
  swig3/trunk/
  swig3/trunk/PKGBUILD

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Added: swig3/trunk/PKGBUILD
===================================================================
--- swig3/trunk/PKGBUILD	                        (rev 0)
+++ swig3/trunk/PKGBUILD	2019-08-02 05:18:07 UTC (rev 496495)
@@ -0,0 +1,35 @@
+# Maintainer: Michael Hansen <zrax0111 gmail com>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgname=swig3
+_pkgname=swig
+pkgver=3.0.12
+pkgrel=1
+pkgdesc="Generate scripting interfaces to C/C++ code (Legacy 3.x version)"
+arch=('x86_64')
+url="http://www.swig.org/"
+license=('custom')
+depends=('pcre' 'gcc-libs')
+checkdepends=('ruby' 'python2' 'java-environment' 'tcl' 'php' 'lua' 'ocaml' 'r' 'go' 'python2-cffi' 'camlp4')
+source=(https://downloads.sourceforge.net/${_pkgname}/${_pkgname}-${pkgver}.tar.gz)
+sha1sums=('5cc1af41d041e4cc609580b99bb3dcf720effa25')
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  ./configure --prefix=/usr --program-suffix="-3"
+  make
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}
+  make check || warning "Tests failed"
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+  install -D -m644 LICENSE-UNIVERSITIES "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE-UNIVERSITIES
+}