[arch-commits] Commit in cairo/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Fri Aug 2 14:59:58 UTC 2019
Date: Friday, August 2, 2019 @ 14:59:57
Author: heftig
Revision: 358891
archrelease: copy trunk to testing-x86_64
Added:
cairo/repos/testing-x86_64/
cairo/repos/testing-x86_64/PKGBUILD
(from rev 358890, cairo/trunk/PKGBUILD)
----------+
PKGBUILD | 66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
Copied: cairo/repos/testing-x86_64/PKGBUILD (from rev 358890, cairo/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2019-08-02 14:59:57 UTC (rev 358891)
@@ -0,0 +1,66 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Brice Carpentier <brice at daknet.org>
+
+pkgname=cairo
+pkgver=1.17.2+17+g52a7c79fd
+pkgrel=1
+pkgdesc="2D graphics library with support for multiple output devices"
+url="https://cairographics.org/"
+arch=(x86_64)
+license=(LGPL MPL)
+depends=(libpng libxrender libxext fontconfig pixman glib2 lzo)
+makedepends=(librsvg gtk2 poppler-glib libspectre gtk-doc valgrind git)
+checkdepends=(ttf-dejavu gsfonts)
+_commit=52a7c79fd4ff96bb5fac175f0199819b0f8c18fc # master
+source=("git+https://gitlab.freedesktop.org/cairo/cairo.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd cairo
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd cairo
+
+ # Update gtk-doc
+ cp /usr/share/aclocal/gtk-doc.m4 build/aclocal.gtk-doc.m4
+ cp /usr/share/gtk-doc/data/gtk-doc.make build/Makefile.am.gtk-doc
+
+ # Fix typo
+ sed -i 's/have_png/use_png/g' configure.ac
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd cairo
+ ./configure --prefix=/usr \
+ --sysconfdir=/etc \
+ --localstatedir=/var \
+ --disable-static \
+ --disable-gl \
+ --enable-tee \
+ --enable-svg \
+ --enable-ps \
+ --enable-pdf \
+ --enable-gobject \
+ --enable-gtk-doc \
+ --enable-full-testing \
+ --enable-test-surfaces
+ sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd cairo
+ # FIXME: tests don't pass
+ env CAIRO_TEST_TARGET=image \
+ CAIRO_TEST_TARGET_FORMAT=rgba \
+ CAIRO_TESTS='!pthread-show-text' make -k check || :
+}
+
+package() {
+ cd cairo
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list