[arch-commits] Commit in fragments/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, August 6, 2019 @ 03:41:00
  Author: foutrelis
Revision: 497551

archrelease: copy trunk to community-staging-x86_64

Added:
  fragments/repos/community-staging-x86_64/
  fragments/repos/community-staging-x86_64/PKGBUILD
    (from rev 497550, fragments/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: fragments/repos/community-staging-x86_64/PKGBUILD (from rev 497550, fragments/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-06 03:41:00 UTC (rev 497551)
@@ -0,0 +1,63 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=fragments
+pkgver=1.4
+pkgrel=2
+pkgdesc="BitTorrent client for GNOME"
+arch=(x86_64)
+url="https://gitlab.gnome.org/World/Fragments"
+license=(GPL3)
+depends=(curl libevent libhandy libnatpmp miniupnpc)
+makedepends=(cmake git meson vala)
+_commit=f91ea9b576f3ff2621d5f3fda417a9a43107607c  # tags/1.4
+source=("git+https://gitlab.gnome.org/World/Fragments/#commit=$_commit"
+        "git+https://github.com/transmission/transmission"
+        "git+https://github.com/transmission/dht"
+        "git+https://github.com/transmission/libb64"
+        "git+https://github.com/transmission/libevent"
+        "git+https://github.com/transmission/libnatpmp"
+        "git+https://github.com/transmission/libutp"
+        "git+https://github.com/transmission/miniupnpc")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd Fragments
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd Fragments
+  git submodule init
+  git config --local submodule.submodules/transmission.url "$srcdir/transmission"
+  git submodule update
+
+  cd submodules/transmission
+  git submodule init
+  git config --local submodule.third-party/dht.url "$srcdir/dht"
+  git config --local submodule.third-party/libb64.url "$srcdir/libb64"
+  git config --local submodule.third-party/libevent.url "$srcdir/libevent"
+  git config --local submodule.third-party/libnatpmp.url "$srcdir/libnatpmp"
+  git config --local submodule.third-party/libutp.url "$srcdir/libutp"
+  git config --local submodule.third-party/miniupnpc.url "$srcdir/miniupnpc"
+  git submodule update
+}
+
+build() {
+  arch-meson Fragments build
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}