[arch-commits] Commit in hoogle/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Aug 6 17:01:31 UTC 2019


    Date: Tuesday, August 6, 2019 @ 17:01:30
  Author: felixonmars
Revision: 497895

archrelease: copy trunk to community-staging-x86_64

Added:
  hoogle/repos/community-staging-x86_64/
  hoogle/repos/community-staging-x86_64/PKGBUILD
    (from rev 497894, hoogle/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: hoogle/repos/community-staging-x86_64/PKGBUILD (from rev 497894, hoogle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-06 17:01:30 UTC (rev 497895)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hoogle
+pkgver=5.0.17.10
+pkgrel=2
+pkgdesc="Haskell API Search"
+url="https://www.haskell.org/hoogle/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-cmdargs' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-connection' 'haskell-extra' 'haskell-foundation' 'haskell-hashable'
+         'haskell-http-conduit' 'haskell-http-types' 'haskell-js-flot' 'haskell-js-jquery'
+         'haskell-mmap' 'haskell-network' 'haskell-old-locale' 'haskell-process-extras'
+         'haskell-resourcet' 'haskell-src-exts' 'haskell-storable-tuple' 'haskell-tar'
+         'haskell-uniplate' 'haskell-utf8-string' 'haskell-vector' 'haskell-wai'
+         'haskell-wai-logger' 'haskell-warp' 'haskell-warp-tls' 'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('7b9a181510ee0555812d1dd3c90ca02e21597732d9881e8be895ef9ffdbfa1f9bf9f3551351493e829852fa0c9b7f57cb405fcae1650efb7ce57dd0aa6d0c5a0')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list